! Esperanto lexicon

Multichar_Symbols
 +Acc	! accusative
 +Adj   ! adjective
 +ASuff ! adjective suffix
 +Aug   ! augmentative
 +Dim   ! diminutive
 +Fem   ! feminine
 MF+    ! male-female
 Op+    ! opposite
 +Neg   ! negative
 +Noun  ! noun
 +NSuff ! noun suffix
 +Pl	! plural j
 +Sg	! singular
 @U.MF.Yes@
 @U.MF.Not@
 @C.MF@

LEXICON Root
  Adjectives ;
  Nouns ;

LEXICON Adjectives
  APrefix ;
  AStem;

LEXICON APrefix
  Neg+:ne AStem;
  Op+:mal AStem;

LEXICON AStem
  alt AMag;
  bon AMag;
  evident AMag;
  grandioz AMag;
  grav AMag;
  ideal AMag;
  jun AMag;
  liber AMag;
  long AMag;
  luks AMag;
  nigr AMag;
  oportun AMag;

LEXICON AMag
  Adj;
  +Aug:eg AMag;
  +Dim:et AMag;

LEXICON Adj
  +Adj:0 AdjOrNoun;

LEXICON AdjOrNoun
  +Adj+Noun:ec NSuff;
  ASuff;

LEXICON ASuff
  +ASuff:a Number;

LEXICON Nouns
  @U.MF.Yes@ MFPref ;
  AnimNouns;

LEXICON MFPref
  MF+:ge AnimNouns;

LEXICON AnimNouns
  best  Nmf;
  bird	Nmf;
  elefant Nmf;
  hund  Nmf;
  kat   Nmf;
  leon  Nmf;
  tigr Nmf;
  
LEXICON Nmf
  +Noun:0 NDeriv;

LEXICON NDeriv
  NounOrAdj;
  @U.MF.Not@ Feminine;
  +Dim:et NDeriv;
  +Aug:eg NDeriv;

LEXICON Feminine
  +Fem:in NDeriv;

LEXICON NounOrAdj
  +Adj:0 ASuff ;
  NSuff;

LEXICON NSuff
  +NSuff:o Number;

LEXICON Number
  @C.MF@ Plural;
  %+Sg:0  Case;

LEXICON Plural
  %+Pl:j  Case;

LEXICON Case
  +Acc:n  CheckOK;
          CheckOK;

LEXICON CheckOK
  @U.MF.Not@ #;