{This is a BNF for PASCAL (doctored a bit).
There are conflicts in the LALR(1) tables                    }

<PROG> -> <PROGRAM> .
<PROGRAM> -> PROGRAM IDEN ( <ID-LIST> ) ; <BLOCK> '. .
<ID-LIST> -> <ID-LIST> , IDEN 
           ! IDEN .
<BLOCK> -> <LAB-PAR> <CONS-PAR> <TYPE-PAR> <VAR-PAR> <PROC-PAR> <MAIN>
           ! <LAB-PAR> <TYPE-PAR> <VAR-PAR> <PROC-PAR> <MAIN> 
           ! <LAB-PAR> <CONS-PAR> <VAR-PAR> <PROC-PAR> <MAIN> 
           ! <LAB-PAR> <CONS-PAR> <TYPE-PAR> <VAR-PAR> <MAIN> 
           ! <LAB-PAR> <VAR-PAR> <PROC-PAR> <MAIN> 
           ! <LAB-PAR> <TYPE-PAR> <VAR-PAR> <MAIN> 
           ! <LAB-PAR> <CONS-PAR> <VAR-PAR> <MAIN> 
           ! <LAB-PAR> <VAR-PAR> <MAIN> 
           ! <CONS-PAR> <TYPE-PAR> <VAR-PAR> <PROC-PAR> <MAIN> 
           ! <TYPE-PAR> <VAR-PAR> <PROC-PAR> <MAIN> 
           ! <CONS-PAR> <VAR-PAR> <PROC-PAR> <MAIN> 
           ! <CONS-PAR> <TYPE-PAR> <VAR-PAR> <MAIN> 
           ! <VAR-PAR> <PROC-PAR> <MAIN> 
           ! <TYPE-PAR> <VAR-PAR> <MAIN> 
           ! <CONS-PAR> <VAR-PAR> <MAIN> 
           ! <VAR-PAR> <MAIN>
           ! <MAIN>.
<MAIN> -> BEGIN <STAT-LST> END 
        ! BEGIN END .
<LAB-PAR> -> LABEL <LAB-LIST> ; .
<LAB-LIST> -> <LAB-LIST> , <LABEL> 
            ! <LABEL> .
<LABEL> -> NUMBER .
<CONS-PAR> -> CONST <CON-DCLL> ; .
<CON-DCLL> -> <CON-DCLL> ; <CON-DCL> 
            ! <CON-DCL> .
<CON-DCL> -> IDEN = <CONSTANT> .
<CONSTANT> -> NUMBER 
            ! ADDOP NUMBER 
            ! IDEN 
            ! ADDOP IDEN 
            ! STRING .
<TYPE-PAR> -> TYPE <TYP-DEFL> ; .
<TYP-DEFL> -> <TYP-DEFL> ; <TYPE-DEF> 
            ! <TYPE-DEF> .
<TYPE-DEF> -> IDEN = <TYPE> .
<TYPE> -> <SIMPL-TY> 
        ! <STRUC-TY> 
        ! <POINT-TY> .
<SIMPL-TY> -> <SCALAR> 
            ! <SUBRANGE> 
            ! IDEN .
<SCALAR> -> ( <ID-LIST> ) .
<SUBRANGE> -> <CONSTANT> '.. <CONSTANT> .
<STRUC-TY> -> <UNPAC-TY> 
            ! PACKED <UNPAC-TY> .
<UNPAC-TY> -> <ARRAY-TY> 
            ! <RECORD-T> 
            ! <SET-TYP> 
            ! <FILE-TYP> .
<ARRAY-TY> -> ARRAY [ <INDEX-TL> ] OF <TYPE> .
<INDEX-TL> -> <INDEX-TL> , <SIMPL-TY> 
            ! <SIMPL-TY> .
<RECORD-T> -> RECORD <FIELD-L> END 
            ! RECORD <REC-SECL> END .
<FIELD-L> -> <REC-SECL> ; <VARIANTP> 
           ! <VARIANTP> .
<REC-SECL> -> <REC-SECL> ; <REC-SEC>  
            ! <REC-SEC> 
            ! <REC-SECL> ; 
            ! ; 
            ! ; <REC-SEC> .
<REC-SEC> -> <ID-LIST> : <TYPE> .
<VARIANTP> -> CASE IDEN : IDEN OF <VARIANTL> 
            ! CASE IDEN OF <VARIANTL> .
<VARIANTL> -> <VARIANTL> ; <VARIANT> 
            ! <VARIANT> 
            ! <VARIANTL> ; 
            ! ; <VARIANT> 
            ! ; .
<VARIANT> -> <CASE-LAB> : ( <FIELD-L> ) 
           !  <CASE-LAB> : ( ) .
<CASE-LAB> -> <CASE-LAB> , <CONSTANT> 
            ! <CASE-LAB> , <SUBRANGE> 
            ! <CONSTANT> 
            ! <SUBRANGE> .
<SET-TYP> -> SET OF <SIMPL-TY> .
<FILE-TYP> -> FILE OF <TYPE> .
<POINT-TY> -> ^ IDEN .
<VAR-PAR> -> VAR <VAR-DCLL> ; 
           ! <VAR-PAR> VAR <VAR-DCLL> ; .
<VAR-DCLL> ->   <VAR-DCLL> '; <VAR-DCL>  
           ! <VAR-DCL> .
<VAR-DCL> ->  <ID-LIST> : <TYPE> .
<PROC-PAR> -> <PROC-PAR>  <PRO-FUN> ; 
            ! <PRO-FUN> ; 
. <PRO-FUN> -> <PROC-HD> <BLOCK>  
! <FUNC-HD> <BLOCK>  
. <PROC-HD> -> PROCEDURE IDEN ; 
! PROCEDURE IDEN ( <FOR-PARL> ) ; 
. <FOR-PARL> -> <FOR-PARL> ; <FOR-PAR> 
! <FOR-PAR> 
. <FOR-PAR> -> <ID-LIST> : <TYPE> 
! VAR <ID-LIST> : <TYPE> 
! FUNCTION <ID-LIST> : <TYPE> 
! PROCEDURE <ID-LIST> 
. <FUNC-HD> -> FUNCTION IDEN : <TYPE> ; 
! FUNCTION IDEN ( <FOR-PARL> ) : <TYPE> ; 
. <STAT-LST> -> <STAT-LST> ; <STAT> 
! <STAT> 
! <STAT-LST> ; 
! ; <STAT> 
! ; 
. <STAT> -> <UN-STAT> 
! <LABEL> : <UN-STAT> 
. <UN-STAT> -> <SIM-STAT> 
! <STR-STAT> 
. <SIM-STAT> -> <VARIABLE> := <EXPR> 
! 'READ-LN  
! 'READ-LN  ( IDEN , <REC-VL> ) 
! 'READ-LN  ( <REC-VL> ) 
! 'WRITE-LN  ( IDEN , <ITEM-LST> ) 
! 'WRITE-LN  ( <ITEM-LST> ) 
! 'WRITE-LN  
! IDEN 
! IDEN ( <EXPR-L> ) 
! GOTO <LABEL> 
. <ITEM-LST> -> <ITEM-LST> , <ITEM> 
! <ITEM> 
. <ITEM> -> <EXPR> 
! <EXPR> : <S-EXPR> 
! <EXPR> : <S-EXPR> : <S-EXPR> 
. <VARIABLE> -> IDEN 
! <VARIABLE> [ <EXPR-L> ] 
! <VARIABLE> '. IDEN 
! <VARIABLE> ^ 
. <EXPR-L> -> <EXPR-L> , <EXPR> 
! <EXPR> 
. <EXPR> -> <S-EXPR> 
!  <S-EXPR> RELOP <S-EXPR> 
! <S-EXPR> = <S-EXPR> 
. <S-EXPR> -> <S-EXPR> ADDOP <S-EXPR> 
! <S-EXPR> MULOP <S-EXPR> 
! ADDOP <S-EXPR> 
! <VARIABLE> 
! NUMBER 
! ( <EXPR> ) 
! STRING 
! NIL 
! IDEN ( <EXPR-L> ) 
! NOT <S-EXPR> 
! [ ] 
! [ <EL-LIST> ] 
. <EL-LIST> -> <EL-LIST>  , <ELEM> 
! <ELEM> 
. <ELEM> -> <EXPR> 
! <EXPR> '.. <EXPR> 
. <STR-STAT> -> BEGIN <STAT-LST> END 
! BEGIN END 
! IF <EXPR> THEN <STAT> 
! IF <EXPR> THEN <STAT-LST> FI 
! IF <EXPR> THEN <STAT-LST> ELSE <STAT> 
! IF <EXPR> THEN <STAT-LST> ELSE <STAT-LST> FI 
! WHILE <EXPR> DO <STAT> 
! WHILE <EXPR> DO <STAT-LST> OD 
! REPEAT <STAT-LST> UNTIL <EXPR> 
! FOR IDEN := <FOR-LIST> DO <STAT> 
! FOR IDEN := <FOR-LIST> DO <STAT-LST> OD 
! CASE <EXPR> OF <CASE-LST> END 
! CASE <EXPR> OF <CASE-LST> ELSE : <STAT-LST> END 
! WITH <REC-VL> DO <STAT> 
! WITH <REC-VL> DO <STAT-LST> OD 
. <CASE-LST> -> <CASE-LST> ; <CASE-LAB> : <STAT> 
! <CASE-LAB> : <STAT> 
! <CASE-LST> ; 
! ; <CASE-LAB> : <STAT> 
! ; 
! <CASE-LAB> : 
. <FOR-LIST> -> <EXPR> TO <EXPR> 
! <EXPR> DOWNTO <EXPR> 
. <REC-VL> -> <REC-VL> , <VARIABLE> 
! <VARIABLE>   
$